Помогите разобраться с QueryBuildDataSource

[raz]

Создаю Lookup метод, для выбора из InventTrans токого TransRefId, который соответсвует таблицам: SalesTable или PurchTable. Т.е. необходимо показать записи, только по этим двум таблицам, остальные не нужны.

В форме один датасорс ссылающийся на таблицу InventTrans.

У него я перекрыл метод Init.

PHP-Code:

public void init()
{
    Query                   query;
    QueryBuildDataSource    qbds_InventTrans;
    QueryBuildDataSource    qbds_SalesTable;
    QueryBuildDataSource    qbds_PurchTable;
    QueryBuildDataSource    qbds_InventJournalTable;
    ;

    super();

    Query = new Query();

    qbds_InventTrans = Query.addDataSource(tablenum(InventTrans));

    qbds_SalesTable = qbds_InventTrans.addDataSource(tablenum(SalesTable));
    qbds_SalesTable.joinMode(JoinMode::ExistsJoin);
    qbds_SalesTable.fetchMode(0);

    qbds_PurchTable = qbds_InventTrans.addDataSource(tablenum(PurchTable));
    qbds_PurchTable.joinMode(JoinMode::ExistsJoin);
    qbds_PurchTable.fetchMode(0);

    qbds_PurchTable.addLink(FieldNum(InventTrans,TransRefId),fieldNum(PurchTable,PurchId));
    qbds_SalesTable.addLink(FieldNum(InventTrans,TransRefId),fieldNum(SalesTable,SalesId));

    this.query(Query);
} 


В результате пустой грид, если оставить один присоединенный датасорс, то видно только относящиеся к нему записи.

Что я делаю не правильно?

[Andrew Besedin]

Привет!
Вот твой SQL - запрос:

PHP-Code:

SELECT * FROM InventTrans 
           EXISTS JOIN * FROM SalesTable WHERE InventTrans.TransRefId = SalesTable.SalesId 
           EXISTS JOIN * FROM PurchTable WHERE InventTrans.TransRefId = PurchTable.PurchId 


Если его написать на Х++, то вернется пустое множество.

А правильный запрос будет такой (на Х++). На TransType внимание не обращай - это не суть:

PHP-Code:

while select InventTrans
    exists join salesTable
        exists join purchTable
                where (InventTrans.TransRefId == salesTable.SalesId && InventTrans.TransType == InventTransType::Sales)
                 ||   ( InventTrans.TransRefId  == purchTable.PurchId && InventTrans.TransType == InventTransType::Purch)
    print InventTrans.ItemId; 


...Но как "выразить" этот селект на языке QBDS - я затрудняюсь...

[Wamr]

для выбора из InventTrans токого TransRefId, который соответсвует таблицам хватит такого запроса

PHP-Code:

select InventTrans 
  where InventTrans.TransType == InventTransType::Sales ||
              InventTrans.TransType == InventTransType::Purch

// или 
qbds.addRange(fieldNum(InventTrans, TransType)).value(queryValue(InventTransType::Sales) + "," + queryValue(InventTransType::Purch)); 


но тормоза обеспечены

[raz]

2 Wamr

Спасибо, но интересует именно мой вопрос.

Т.к. таблица InventTrans общая для нескольких компаний, и меня интересуют записи только текущей компании.

[raz]

Вижу идей больше нет.

Тогда может кто нибудь подскажет, как у датасорса подменить курсор?

[Andrew Besedin]

Привет raz!

Вот работающий код:

PHP-Code:

public void init()
{
    Query                   query;
    QueryBuildDataSource    qbds_InventTrans;
    QueryBuildDataSource    qbds_SalesTable;
    QueryBuildDataSource    qbds_PurchTable;
    QueryBuildDataSource    qbds_InventJournalTable;
    SalesTable SalesTable;
    ;
    super();
    Query = new Query();
    qbds_InventTrans = Query.addDataSource(tablenum(InventTrans),"it");

    qbds_PurchTable = qbds_InventTrans.addDataSource(tablenum(PurchTable),"_pt");
    qbds_PurchTable.joinMode(JoinMode::ExistsJoin);
    qbds_PurchTable.fetchMode(0);
    qbds_PurchTable.relations(false);

    qbds_SalesTable = qbds_InventTrans.addDataSource(tablenum(SalesTable),"st");
    qbds_SalesTable.joinMode(JoinMode::ExistsJoin);
    qbds_SalesTable.fetchMode(0);
    qbds_InventTrans.relations(false);

    qbds_SalesTable.addRange(fieldnum(SalesTable,salesID)).value("( (iT.transRefID == sT.salesID) || (iT.transRefID == _pT.purchID) )");

    this.query(Query);
    Info(this.query().dataSourceNo(1).tostring());
} 


Идею подсказал Денис Федотенко, когда делился "стратегическим знанием"
вот ссылка на его постинг:http://www.axforum.info/forums/showt...=1634#post1634

Вопрос по ходу: что за волшебный идентификатор такой "pt" - из-за него не работало нифига...

[raz]

2 Andrew Besedin

Спасибо!!!
Все работает!!!

А я уже хотел делать с дополнительным контролом ComboBox, для предварительного выбора Заказ, Закупка, Журнал.

[raz]

Странное дело, немного модифицировал метод inti, что бы добавить выбор складских журналов и ...

Именно журналы не показываются, а закупки и заказы видны.

Не пойму в чем дело.

PHP-Code:

public void init()
{
    Query                   query;
    QueryBuildDataSource    qbds_InventTrans;
    QueryBuildDataSource    qbds_SalesTable;
    QueryBuildDataSource    qbds_PurchTable;
    QueryBuildDataSource    qbds_InventJournalTable;
    ;
    super();
    Query = new Query();
    qbds_InventTrans = Query.addDataSource(tablenum(InventTrans),"_InventTrans");

    qbds_PurchTable = qbds_InventTrans.addDataSource(tablenum(PurchTable),"_PurchTable");
    qbds_PurchTable.joinMode(JoinMode::ExistsJoin);
    qbds_PurchTable.fetchMode(0);
    qbds_PurchTable.relations(false);

    qbds_SalesTable = qbds_InventTrans.addDataSource(tablenum(SalesTable),"_SalesTable");
    qbds_SalesTable.joinMode(JoinMode::ExistsJoin);
    qbds_SalesTable.fetchMode(0);
    qbds_InventTrans.relations(false);

    qbds_InventJournalTable = qbds_InventTrans.addDataSource(tablenum(InventJournalTable),"_InventJournalTable");
    qbds_InventJournalTable.joinMode(JoinMode::ExistsJoin);
    qbds_InventJournalTable.fetchMode(0);
    qbds_InventTrans.relations(false);

    qbds_InventJournalTable.addRange(fieldnum(InventJournalTable,JournalId)).value("( (_InventTrans.TransRefId == _SalesTable.SalesId) ||" +
                                                                                   " (_InventTrans.TransRefId == _PurchTable.PurchId) ||" +
                                                                                   " (_InventTrans.TransRefId == _InventJournalTable.JournalId) )");


    this.query(Query);

//    Info(this.query().dataSourceNo(1).tostring()); 
//   SELECT * FROM InventTrans EXISTS JOIN * FROM PurchTable EXISTS JOIN * FROM SalesTable EXISTS JOIN * FROM InventJournalTable WHERE ((( (_InventTrans.TransRefId == _SalesTable.SalesId) || (_InventTrans.TransRefId == _PurchTable.PurchId) || (_InventTrans.TransRefId == _InventJournalTable.JournalId) )))
} 


[Andrew Besedin]

Привет Raz!

...Интере-е-есные вопросы задаешь, однако
Т.к. нормальные герои всегда идут в обход - предлагаю связать InventTrans с InventJournalTrans по полю InventTransID.
Работает гарантировано и решает твою задачу!

[dn]

Может быть поэтому:
InventTransRefId: string size 20, Adjustment Right
InventJournalId: string size 10, Adjustment Right

[Andrew Besedin]

Привет Эдуард!

PHP-Code:

public void init()
{
    Query                   query;
    QueryBuildDataSource    qbds_InventTrans;
    QueryBuildDataSource    qbds_SalesTable;
    QueryBuildDataSource    qbds_PurchTable;
    QueryBuildDataSource    qbds_InventJournalTrans;
    ;
    super();
    Query = new Query();
    qbds_InventTrans = Query.addDataSource(tablenum(InventTrans),"it");
    qbds_InventTrans.relations(false);


    qbds_PurchTable = qbds_InventTrans.addDataSource(tablenum(PurchTable),"_PT");
    qbds_PurchTable.joinMode(JoinMode::ExistsJoin);
    qbds_PurchTable.fetchMode(0);
    qbds_PurchTable.relations(false);

    qbds_SalesTable = qbds_InventTrans.addDataSource(tablenum(SalesTable),"_ST");
    qbds_SalesTable.joinMode(JoinMode::ExistsJoin);
    qbds_SalesTable.fetchMode(0);
    qbds_SalesTable.relations(false);

    qbds_InventJournalTrans = qbds_InventTrans.addDataSource(tablenum(InventJournalTrans),"ijt");
    qbds_InventJournalTrans.joinMode(JoinMode::ExistsJoin);
    qbds_InventJournalTrans.fetchMode(0);

    qbds_InventJournalTrans.relations(false);

    qbds_InventJournalTrans.addRange(fieldnum(InventJournalTrans,journalID)).value("( (iT.transRefID == _sT.salesID) || (iT.transRefID == _pT.purchID) || (it.InventTransID == ijt.InventTransID) )");
    this.query(Query);

    Info(this.query().dataSourceNo(1).tostring());
} 


2 DN
Ты абсолютно прав насчет разных длин у EDT. Поэтому селект будет такой:

PHP-Code:

static void Job4(Args _args)
{

InventJournalTable InventJournalTable;
InventTrans InventTrans;

while select InventTrans
   join InventJournalTable
    where InventTrans.TransRefId like /*!!! Равенство не работает!!!*/ InventJournalTable.JournalId
        print InventTrans.TransRefId;
pause;
} 


Но как этот LIKE затолкать в QBDS - хто бы знал