Связь CustInvoiceJour и InventTrans - DAX: Программирование

Silphidae · 28.10.2009, 13:30

Добрый день

Прошу помочь разобраться с такой проблемой. Пытаюсь сделать такой запрос:

X++:

    Query q;
    QueryBuildDataSource qbdsCustInvoiceJour;
    QueryBuildDataSource qbdsInventTrans;
    QueryBuildRange      range;
    Str600               value;
    ;

    q = new Query();
    qbdsCustInvoiceJour = q.addDataSource(tableNum(CustInvoiceJour), "CJTable");
    qbdsCustInvoiceJour.addSelectionField(fieldNum(CustInvoiceJour, InvoiceAccount));
    qbdsCustInvoiceJour.addSelectionField(fieldNum(CustInvoiceJour, InvoiceId));
    qbdsCustInvoiceJour.addSelectionField(fieldNum(CustInvoiceJour, SalesId));
    range = qbdsCustInvoiceJour.addRange(fieldNum(CustInvoiceJour, InvoiceAccount));
    range.value("39");

    qbdsInventTrans = qbdsCustInvoiceJour.addDataSource(tableNum(InventTrans),"ITTable");
    qbdsInventTrans.addLink(fieldNum(CustInvoiceJour, InvoiceId),fieldNum(InventTrans, InvoiceId));
    qbdsInventTrans.addLink(fieldNum(CustInvoiceJour, SalesId), fieldNum(InventTrans, TransRefId));
    qbdsInventTrans.addSelectionField(fieldNum(InventTrans, RecId));

Т.е. просто выбираю запись из InventTrans с номером заказа на продажу и инвойсом как в таблице CustInvoiceJour.
Но это не работает. И проблема, как мне кажется в разных EDT у полей связи, хотя, по сути, они содержат одинаковую информацию.
Возможно, есть какой-то аналог LIKE для qbds или какой-нибудь статик_каст для преобразования типов?

raz · 28.10.2009, 13:33

добавьте строки накладных, будет быстрее и заработает. проблема скопее всего в выравнивании TransRefId

CustInvoiceJour->CustInvoiceTrans->InventTrans

raz · 28.10.2009, 13:38

X++:

    Query q;
    QueryBuildDataSource qbdsCustInvoiceJour;
    QueryBuildDataSource qbdsCustInvoiceTrans;
    QueryBuildDataSource qbdsInventTrans;
    QueryBuildRange      range;
    Str600               value;
    ;

    q = new Query();
    qbdsCustInvoiceJour = q.addDataSource(tableNum(CustInvoiceJour), "CJTable");
    qbdsCustInvoiceJour.addSelectionField(fieldNum(CustInvoiceJour, InvoiceAccount));
    qbdsCustInvoiceJour.addSelectionField(fieldNum(CustInvoiceJour, InvoiceId));
    qbdsCustInvoiceJour.addSelectionField(fieldNum(CustInvoiceJour, SalesId));
    range = qbdsCustInvoiceJour.addRange(fieldNum(CustInvoiceJour, InvoiceAccount));
    range.value("39");

    qbdsCustInvoiceTrans= qbdsCustInvoiceJour.addDataSource(tableNum(CustInvoiceTrans));
    qbdsCustInvoiceTrans.addLink(fieldNum(CustInvoiceJour, InvoiceId),fieldNum(CustInvoiceTrans, InvoiceId));
    qbdsCustInvoiceTrans.addLink(fieldNum(CustInvoiceJour, SalesId), fieldNum(CustInvoiceTrans, SalesId));
    qbdsCustInvoiceTrans.addLink(fieldNum(CustInvoiceJour, InvoiceDate), fieldNum(CustInvoiceTrans, InvoiceDate));
    qbdsCustInvoiceTrans.addLink(fieldNum(CustInvoiceJour, numberSequenceGroup), fieldNum(CustInvoiceTrans, numberSequenceGroup));

    qbdsInventTrans = qbdsCustInvoiceTrans.addDataSource(tableNum(InventTrans),"ITTable");
    qbdsInventTrans.addLink(fieldNum(qbdsCustInvoiceTrans, InventTransId),fieldNum(InventTrans, InventTransId));
    qbdsInventTrans.addLink(fieldNum(qbdsCustInvoiceTrans, InvoiceId),fieldNum(InventTrans, InvoiceId));
    qbdsInventTrans.addLink(fieldNum(qbdsCustInvoiceTrans, InvoiceDate),fieldNum(InventTrans, DateFinancial));
    qbdsInventTrans.addSelectionField(fieldNum(InventTrans, RecId));

Silphidae · 28.10.2009, 13:38

Zitat:

добавьте строки накладных, будет быстрее и заработает. проблема скопее всего в выравнивании TransRefId
CustInvoiceJour->CustInvoiceTrans->InventTrans

Спасибо, raz
К сожалению, такой вариант не рассматривается, ибо я решаю обратную задачу - нужно CustInvoiceJour->InventTrans->CustInvoiceTrans

SRF · 28.10.2009, 14:50

Добрый день!

Попробуйте вместо строки

X++:

qbdsInventTrans.addLink(fieldNum(CustInvoiceJour, SalesId), fieldNum(InventTrans, TransRefId));

строку

X++:

qbdsInventTrans.addLink(fieldNum(CustInvoiceJour, LedgerVoucher), fieldNum(InventTrans, Voucher));

P.S. Точно не уверен, что будет работать во всех вариантах, нужно тестировать. Еще также желательно добавить индекс по полю Voucher.

Wamr · 28.10.2009, 14:54

можно через Voucher + DateFinancial = LederVoucher + InvoiceDate
но это очень тяжелый вариант, так как поля неиндексированы.

В качестве альтернативы можно через SalesLine
CustInvoiceJour -> SalesId
SalesLine -> InventTransId
InventTrans (InvoiceId)

Logger · 28.10.2009, 15:27

Zitat:

Zitat von raz

проблема скопее всего в выравнивании TransRefId

Нее. У них же общий предок Num.

Silphidae · 28.10.2009, 17:23

Спасибо всем.
Пожалуй, буду использовать вариант через SalesLine.

Однако для образования хотелось бы узнать, есть ли способ насильно преобразовывать типы. И есть ли возможность писать like в qbds.

lev · 28.10.2009, 17:28

Zitat:

Zitat von Silphidae

Спасибо всем.
Пожалуй, буду использовать вариант через SalesLine.

Однако для образования хотелось бы узнать, есть ли способ насильно преобразовывать типы. И есть ли возможность писать like в qbds.

вот пример вставки LIKE:

X++:

Query                   query = new Query();
    QueryBuildDataSource    qbds;
    str                                 itemLike = 'Ном';
    ;

    qbds = query.addDataSource(tablenum(InventTable));
    qbds.addRange(fieldNum(InventTable, ItemId)).value(strFmt('*%1*', itemLike));

    info(qbds.toString());

а про приобразование каких типов вы имеете ввиду?

lev · 28.10.2009, 17:36

почему я спросил про какие типы идет речь...
в стандарте есть много всяких функций преобразования типа (num2str(), str2date(), any2real() и т.д.и т.п)

или вы про какое то другое преобразование?

Lemming · 28.10.2009, 18:01

Zitat:

Zitat von Silphidae

Спасибо всем.
Пожалуй, буду использовать вариант через SalesLine.

Блеск...связываем транзакции через строки "черновика", которые можно и изменить, и вообще удалить

Wamr · 28.10.2009, 18:33

2 Lemming

Zitat:

Zitat von Silphidae

К сожалению, ... я решаю обратную задачу - нужно CustInvoiceJour->InventTrans->CustInvoiceTrans

Какова задача, таково и решение

**mazzy** · 28.10.2009, 18:40

Zitat:

Zitat von Silphidae

Пожалуй, буду использовать вариант через SalesLine

Ни в коем случае!!!!

Потому что Lemming правильно написал:

Zitat:

Zitat von Lemming

...через строки "черновика", которые можно и изменить, и вообще удалить

Zitat:

Zitat von Wamr

В качестве альтернативы можно через SalesLine
CustInvoiceJour -> SalesId
SalesLine -> InventTransId
InventTrans (InvoiceId)

Wamr, ну разве ж так можно?
"Кто соблазнит одного из малых сих, тому лучше было бы, если бы повесили ему жерновный камень на шею и бросили его в море"

Lemming · 28.10.2009, 18:52

Zitat:

Zitat von Wamr

2 Lemming
Какова задача, таково и решение

Zitat:

Zitat von Wamr

CustInvoiceJour -> SalesId
SalesLine -> InventTransId
InventTrans (InvoiceId)

Более того, Вы представляете как будет тормозить такое решение на большом кол-ве заказов, инвойсов и складских операций? Вообще абсурд какой-то: стучаться из шапки инвойсов, в строки, через две таблы, наполненные немалым кол-вом данных! Лучше пусть тредстартер конкретизирует задачу, возможно он зашел к решению совсем не с той стороны.

Silphidae · 29.10.2009, 11:01

Zitat:

или вы про какое то другое преобразование?

В с++ были такие вещи как static_cast и dynamic_cast. Вот интересно, есть ли аналоги в х++.
Хотя, конечно, к данной теме это не относится.

Zitat:

Лучше пусть тредстартер конкретизирует задачу, возможно он зашел к решению совсем не с той стороны.

Вполне возможно.. Далается запрос CustInvoiceJour->CustInvoiceTrans->InventItemAndClass, в котором накладываются фильтры по клиентам, датам и узлам классификатора. Нужно еще вкорячить фильтр по складу. Проблема в том, что CustInvoiceTrans группируется по ItemId - и считает сумму по InventQty и LineAmount - тем самым InventDimId из CustInvoiceTrans уже не взять, вот я и хотел перед этим вставить InventTrans, чтобы там делать фильтр по складу.

S.Kuskov · 29.10.2009, 11:30

Zitat:

Zitat von Silphidae

Проблема в том, что CustInvoiceTrans группируется по ItemId - и считает сумму по InventQty и LineAmount.

Не понял, как наличие группировки может помешать добавить ограничение?

Zitat:

Zitat von Silphidae

InventDimId из CustInvoiceTrans уже не взять

Это почему же?

Вот такая конструкция

X++:

select sum(InventQty), sum(LineAmount) from CustInvoiceTrans 
exists join InventDim
where
    InventDim.InventDimId == CustInvoiceTrans.InventDimId &&
    InventDim.InventLocationId == "..."

прекрасно справляется с вашей задачей

Wamr · 29.10.2009, 11:35

mazzy, Lemming, ну конечно нельзя, ну конечно тормоза, понятно что это ИЗВРАТ
но, если потеряна связь CustInvoiceJour - CustInvoiceTrans или кто-то удалил CustInvoiceTrans
и надо это починить - то можно как угодно
видимо с задачей я не угадал

Wamr · 29.10.2009, 11:38

Все-таки raz был прав

Zitat:

Zitat von raz

добавьте строки накладных, будет быстрее и заработает. проблема скопее всего в выравнивании TransRefId

CustInvoiceJour->CustInvoiceTrans->InventTrans

-> InventDim и фильтруй себе по складу

ice · 29.10.2009, 11:55

Zitat:

Zitat von Silphidae

Далается запрос CustInvoiceJour->CustInvoiceTrans->InventItemAndClass, в котором накладываются фильтры по клиентам, датам и узлам классификатора. Нужно еще вкорячить фильтр по складу. Проблема в том, что CustInvoiceTrans группируется по ItemId - и считает сумму по InventQty и LineAmount - тем самым InventDimId из CustInvoiceTrans уже не взять, вот я и хотел перед этим вставить InventTrans, чтобы там делать фильтр по складу.

все фильтры выполняюстя в запросе до того как происходит группировка

Silphidae · 29.10.2009, 15:18

Zitat:

все фильтры выполняюстя в запросе до того как происходит группировка

Я думал, что фильтры кладутся после группировки - поэтому и городил огород.

Спасибо за ответы. Прошу прощения за глупые вопросы.
Но вот если бы я не спросил, кто знает, когда бы я дошел до этого знания - так что не ругайте сильно.

Ähnliche Themen
Thema	Autor	Forum	Antworten	Letzter Beitrag
InventTransIdReturn и Закрытие склада	DenisS	DAX: Программирование	15	03.12.2008 09:02
Достаточно ли изменить дату в таблицах inventTrans, inventTransPosting, VendPackingSlipJour?	DmitryS	DAX: Программирование	3	18.09.2008 14:37
Как правильно достучаться из InventTrans до даты накладыной	NJD	DAX: Программирование	6	22.07.2005 20:52
Связь таблиц InventTrans и PurchLine	Pustik	DAX: Программирование	2	25.11.2004 12:23
Ошибка при связывании InventTrans и InventJournaTable	LCh	DAX: Программирование	2	30.05.2004 15:22