Как разорвать dynalink в журналах?

[deo]

Здравствуйте!

Форма2 вызывается из формы1. Все стандартные связи работаю правильно: когда открыты обе формы, то перемещаясь по записям формы1 обновляются связанные записи формы2. Эти две формы созданы на основе стандартного журнального фреймворка.

Подскажите пожалуйста, как в таком случае разорвать dynalink? Т.е. journalTrans (форма2) открывшись с определенным набором записей не должна обновляться при перемещении курсора по journalTable (форма1).

[sukhanchik]

В форме2, в методе init датасорса, на который накладывается ненужный dynalink - можно вставить код:

    Query                query   = new Query();
    Query                dsquery = _ds.query();
    QueryBuildDataSource qbds;
    ;
    super();
    dsquery = _ds.query();
    qbds = dsquery.dataSourceName(_ds.name());
    SysQuery::queryAddDynaCursorAsRangeAndValue(query, dsquery, qbds.id());
    _ds.query(query);

[gl00mie]

У механизма dynalink есть еще одна неприятная особенность: даже если вы вытрете dynalink из запроса, даже если вы вытрете element.args().record() - все равно у вас будет дергаться linkActive() при каждом телодвижении на вызывающей форме, пусть и вхолостую. Единственный известный мне способ бороться с этим: запомнить переданную при вызове формы запись и вытереть ссылку на нее из element.args().record() ДО вызова init() формы.

[sukhanchik]

Исправил ошибку в коде в своем сообщении.

Zitat:

Zitat von gl00mie

все равно у вас будет дергаться linkActive() при каждом телодвижении на вызывающей форме, пусть и вхолостую.

Есть такой момент... Но если речь идет о том, чтобы не менялся набор записей в вызываемой форме при условии отсутствия перекрытого метода linkActive - то приведенного мною примера достаточно. Хотя "зарубку" в отношении этой особенности оставить себе надо

[DSPIC]

Zitat:

Zitat von sukhanchik

В форме2, в методе init датасорса, на который накладывается ненужный dynalink - можно вставить код:

    Query                query   = new Query();
    Query                dsquery = _ds.query();
    QueryBuildDataSource qbds;
    ;
    super();
    dsquery = _ds.query();
    qbds = dsquery.dataSourceName(_ds.name());
    SysQuery::queryAddDynaCursorAsRangeAndValue(query, dsquery, qbds.id());
    _ds.query(query);

Ой! А что за метод queryAddDynaCursorAsRangeAndValue?
Если я правильно понял коммент:

Zitat:

// This method will traverse dynalinks on QueryBuildDataSource represented by _queryDynaBdsNo
// and convert current dyna-record into ranges and values on that QueryBuildDataSource

, то он конвертит Dynalinks в статические Ranges+Values. Т.е. в данном случае, при открытии дочерней формы "Dynalink" один раз таки сработает, после чего дочерний курсор "отвяжется"?

Спасибо, интересно.

Я пользовался такой конструкцией:

this.query().dataSourceTable(tablenum(Address)).clearDynalinks();

Как я понимаю - тоже самое, но без первого спозиционирования?

[ice]

2 sukhanchik: а можно привести исходный код медода queryAddDynaCursorAsRangeAndValue(), а то у меня его нет

[DSPIC]

Zitat:

Zitat von ice

2 sukhanchik: а можно привести исходный код медода queryAddDynaCursorAsRangeAndValue(), а то у меня его нет

// This method will traverse dynalinks on QueryBuildDataSource represented by _queryDynaBdsNo
// and convert current dyna-record into ranges and values on that QueryBuildDataSource
static client server void queryAddDynaCursorAsRangeAndValue(
    Query   _query,             // new query
    Query   _queryDyna,         // query having external links (=dyna links)
    Integer _queryDynaBdsNO     // queryBuildDataSource on _queryDyna having external links
    )
{
    QueryBuildRange     toQbr;
    QueryBuildDynalink  qbDyna;
    Counter             dynaLinkNo = 1;
    Counter             toI;
    DictField           dictField;
    Integer             dictIndex;
    Integer             originalId;
    Integer             queryDsNO = _queryDynaBdsNO;
    fieldId             id;
    ;
    if (!_queryDynaBdsNO)
        return;

    if (!_query || !_queryDyna)
        throw error(strfmt("@SYS23669",funcname()));

    if (!_queryDyna.dataSourceNo(_queryDynaBdsNO))
        throw error(strfmt("@SYS23667",funcname()));

    if (_query.dataSourceCount() < _queryDynaBdsNO || _query.dataSourceNo(_queryDynaBdsNO).file() != _queryDyna.dataSourceNo(_queryDynaBdsNO).file())
    {
        _query.addDataSource(_queryDyna.dataSourceNo(_queryDynaBdsNO).file());
        queryDsNO = _query.dataSourceCount();
    }
    while (dynaLinkNo <= _queryDyna.dataSourceNo(_queryDynaBdsNO).dynalinkCount())
    {
        qbDyna      = _queryDyna.dataSourceNo(_queryDynaBdsNO).dynalink(dynaLinkNo);
        id          = fieldExt2Id(qbDyna.field());
        originalId  = id;
        toQbr       = null;

        if (_query.dataSourceNo(queryDsNO).findRange(id))
        {
            toI = 1;
            while (true)
            {
                toQbr  = _query.dataSourceNo(queryDsNO).findRange(id,toI);
                if (!toQbr || !toQbr.value() || toQbr.value() == queryValue(qbDyna.cursor().(qbDyna.dynamicField())))
                    break;
                toI++;
            }
        }
        if (!toQbr || (toQbr && toQbr.value() && queryValue(qbDyna.cursor().(qbDyna.dynamicField())) && toQbr.value() != queryValue(qbDyna.cursor().(qbDyna.dynamicField()))))
        {
            // is this a Dimension field?
            dictField = new DictField(_query.dataSourceNo(queryDsNO).table(),id);

            if (dictField.arraySize() > 1)
            {
                // yes, working with Array field
                dictIndex = originalId >> 16;
                toQbr  = _query.dataSourceNo(queryDsNO).addRange(fieldId2Ext(id, dictIndex));
            }
            else
            {
                toQbr  = _query.dataSourceNo(queryDsNO).addRange(id);
            }
        }
        if (toQbr)
            toQbr.value(queryValue(qbDyna.cursor().(qbDyna.dynamicField())));

        dynaLinkNo++;
    }
}

[sukhanchik]

Zitat:

Zitat von DSPIC

Ой! А что за метод queryAddDynaCursorAsRangeAndValue?
Если я правильно понял коммент:


, то он конвертит Dynalinks в статические Ranges+Values. Т.е. в данном случае, при открытии дочерней формы "Dynalink" один раз таки сработает, после чего дочерний курсор "отвяжется"?

Спасибо, интересно.

Я пользовался такой конструкцией:

this.query().dataSourceTable(tablenum(Address)).clearDynalinks();

Как я понимаю - тоже самое, но без первого спозиционирования?

clearDynalinkls() очистит просто диналинки (и соотв снимутся фильтры, а не просто пропадет позиционирование). А тут (важно) - сохранится условие фильтрации (записи будут не все). Этот метод удобно использовать - если нужно запаковать Query (как известно - query, содержащие диналинки не пакуются) - и я его использовал именно для этих целей.

Да, конечно, после убирания диналинка - курсор "отвяжется". Это заметно на ряде форм, которые открываются без диналинков - например, форма Работа с документами (DocuView). Там эффект диналинка делается "вручную" на init и executeQuery датасорса. Плюс также переход к исходному документу из бух проводок к примеру также для каждой строки нужно делать (т.е. формы отвязаны)

Вообще - класс SysQuery достаточно интересный в плане наличия в нем методов. (DAX 4.0 SP2)

[deo]

Вроде как работает
Всем огромное спасибо за помощь!