Обход проектов

[AndyD]

PHP код:

#AOT
#TreeNodeSysNodeType
static void Job5(Args _args)
{
    ProjectNode             prjNode;
    TreeNode                treeNode;
    TreeNodeIterator        it;
    #define.prjname("MyProject")

    void    GetTreeNode(TreeNode parentNode)
    {
        TreeNode                tn;
        TreeNodeIterator        it1;
        ;

        if (parentNode.AOTchildNodeCount())
            setprefix(parentNode.treeNodeName() + ":" + enum2str(parentNode.applObjectType()));
        it1 = parentNode.AOTIterator();
        tn = it1.next();
        while (tn)
        {
            if (tn.AOTchildNodeCount())
                GetTreeNode(tn);
            else
                info(tn.treeNodeName());

            tn = it1.next();
        }
    }
    void    GetProjectGroup(ProjectGroupNode parentNode)
    {
        TreeNode                tn;
        TreeNodeIterator        it1;
        ;
        setprefix(parentNode.treeNodeName());

        it1 = parentNode.AOTIterator();
        tn = it1.next();
        while (tn)
        {
            if (tn.sysNodeType() == #NT_PROJECT_GROUP)
                GetProjectGroup(tn);
            else
            {
                if (tn.AOTchildNodeCount())
                {
                    setprefix(tn.treeNodeName() + ":" + enum2str(tn.applObjectType()));
                    GetTreeNode(tn);
                }
                else
                    info(tn.treeNodeName());
            }
            tn = it1.next();
        }
    }
    ;
    prjNode = infolog.projectRootNode().AOTfindChild("Shared");
    if (prjNode) prjNode = prjNode.AOTfindChild(#prjname);

    if (prjNode)
    {
        prjNode = prjNode.loadForInspection();

        it = prjNode.AOTiterator();

        treeNode = it.next();
        while (treeNode)
        {
            if (treeNode.sysNodeType() == #NT_PROJECT_GROUP)
            {
                setPrefix(prjNode.treeNodeName());
                GetProjectGroup(treeNode);
            }
            else
            {
                if (treeNode.AOTchildNodeCount())
                {
                    setPrefix(prjNode.treeNodeName() + ":" + enum2str(prjNode.applObjectType()));
                    GetTreeNode(treeNode);
                }
                else
                    info(treeNode.treeNodeName());
            }
            treeNode = it.next();
        }

    }
}