InventRepJournalTable_RU

[in.dc]

Реанимирую немного давно забытую тему.

Цитата:

Сообщение от Peter Savintsev

Кстати, удаляются записи из InventJournalReportParms_RU очень просто. Достаточно в форме название складских журналов нажать кнопочку "Обновить". По идее это надо делать один единственный раз при настройки системы. Но уже в ходе эксплуатации можно нечаянно нажать на эту кнопку и все - никаких отчетов (требований-накладных, актов на списание и т.д.) по складским журналам.

В ходе эксплуатации иногда (редко, но бывает) возникает 'осознанная' необходимость нажать на кнопку "Обновить" на форме InventJournalName: при добавлении новых типов складских отчетов на базе InventJournalReport_RU - для актуализации списка доступных печатных форм.

То что при этом удаляются ранее выбранные отчеты для наименований журналов - пожалуй что можно отнести к багам (недоработке) этого куска функционала. Не совсем понятно почему ситуация не меняется от версии к версии: аналогичное поведение наблюдается и в AX 4.0 SP2, на днях посмотрел локализованный код AX2009 - при беглом просмотре метод InventJournalReportTypes_RU::initTable() не изменился (визуально).

Цитата:

Сообщение от Peter Savintsev

...
А еще лучше чуть-чуть подправить в коде: в методе InventJournalReportTypes_RU::initTable() закомментировать строчку

PHP код:

delete_from reportsTable; 


Предложенный вариант (убрать удаление из InventJournalReportParms_RU) может иметь побочный эффект от оставшегося там 'мусора' для случая когда в отчетах будет удаляться тип журнала для которого он доступен: допустим был создан новый отчет InventJournalReport_Example_RU для журналов типа 'Проводка' и 'Инвентаризация', после нажатия кнопки "Обновить" (при предложенной модификации) сохранятся текушие настройки журналов и в списке доступных появится новая форма. Добавляем новую форму в пару журналов 'Проводка' (Y)и 'Инвентаризация' (X). Далее для созданного отчета программист убирает возможность печати для журнала 'Инвентаризация'. Вновь жмем кнопку "Обновить". У журнала инвентаризации X для которого ранее был выбран отчет Example в списке 'Выбрано' этого отчета не будет, т.к. в методе InventJournalNameForm_RU.updateControls() цикл организован по таблице InventJournalReportTypes_RU (в которой уже нет записи о поддержке отчета Example для журналов типа 'Инвентаризация') и решение в каком списке отразить отчет принимается на основании того есть ли запись в InventJournalReportParms_RU (хотя запись в этой таблице не удалена, в анализе она не используется):

public void updateControls()
{
    ...
    while select ReportType, Description from reportTypesTable
        where reportTypesTable.JournalType == inventJournalName.JournalType
    {
        select firstonly RecId from inventReportParms
            where inventReportParms.ReportType            == reportTypesTable.ReportType &&
                  inventReportParms.InventJournalNameId   == inventJournalName.JournalNameId;

        if (inventReportParms.RecId)
        {
            //BP deviation documented
            selectedItemsCtrl.addItem(new FormListItem(reportTypesTable.Description, 0, inventReportParms.ReportType));
        }
        else
        {
            //BP deviation documented
            availableItemsCtrl.addItem(new FormListItem(reportTypesTable.Description, 0, reportTypesTable.ReportType));
        }
    }
    ...
}

При этом d списке отчетов которые можно распечатать по журналу вида X (типа 'Инвентаризация') на форме InventJournalTable (кнопка "Печать") формируемых в методе InventJournalFormTable.updateQueries_RU() отчет Example будет отображаться, т.к. в методах InventJournalProforma_RU::buildReportList() и InventJournalReport_RU::buildReportList() выборка делается по таблице InventJournalReportParms_RU (в которой запись о поддержке отчета Example для журнала X типа 'Инвентаризация' осталась).
Понятно что описанная ситуация имеет несколько искусственный характер, но все же.

Для целостности картины в методе InventJournalReportTypes_RU::initTable() необходимо все-таки удалять записи из таблицы InventJournalReportParms_RU, но не столь 'сурово' как в штатном функционале:

delete_from reportsTable;

а только те, для которых тип поддерживаемого отчета более не актуален, видится это примерно таким образом (немного дополняя вариант с отменой полного удаления строк):

public server static void initTable()
{
    DictEnum                    journalTypeEnum = new DictEnum(enumnum(InventJournalType));
    DictEnum                    reportTypeEnum  = new DictEnum(enumnum(InventJournalReportType_RU));
    int                         idx, jdx;
    InventJournalType           journalType;
    InventJournalReportType_RU  reportType;
    InventJournalReport_RU      report;
    InventJournalReportTypes_RU reportTypesTable;
    InventJournalReportParms_RU reportsTable;
    //  --> in.dc
    InventJournalName           inventJournalName ;
    //  <-- in.dc
    ;

    delete_from reportTypesTable;
    //  --> in.dc
    // delete_from reportsTable;
    //  <-- in.dc

    for(idx = 0; idx < reportTypeEnum.values(); idx++)
    {
        reportType = reportTypeEnum.index2Value(idx);

        report = InventJournalReport_RU::construct(reportType);

        for(jdx = 0; jdx < journalTypeEnum.values(); jdx++)
        {
            journalType = journalTypeEnum.index2Value(jdx);

            if (report.isJournalTypeSupported(journalType))
            {
                reportTypesTable.clear();

                reportTypesTable.JournalType = journalType;
                reportTypesTable.ReportType  = reportType;
                reportTypesTable.Description = report.description();

                reportTypesTable.insert();
            }
        }
    }

    //  --> in.dc
    delete_from reportsTable
        notexists join reportTypesTable
            where   reportTypesTable.ReportType  ==  reportsTable.ReportType
            join    inventJournalName
                where   inventJournalName.JournalNameId ==  reportsTable.InventJournalNameId &&
                        inventJournalName.JournalType   ==  reportTypesTable.journalType ;
    //  <-- in.dc
}

P.S. Тестировалось на DAX 4.0. Хотелось бы услышать комментарии и дополнения по этому предложенному варианту.