про Dialog

[Владимир Максимов]

Цитата:

Сообщение от HorrR

Помогло другое: собсна использование items, item и text вместо add В любом случае спасибо)

Можно и add() использовать, но только после инициализации формы диалога. Примерно так:

static void Test_Dialog(Args _args)
{
    Dialog              dialog;
    FormComboBoxControl fcbc;
    DialogField         dfTest;
    boolean             isOk;
    FormBuildComboBoxControl    buildCombo;
    ;

    dialog = new Dialog();

    // Вариант через дизайн формы ДО инициализации формы диалога
    buildCombo = dialog.formBuildDesign().addControl(FormControlType::COMBOBOX, '');

    buildCombo.items(3);

    buildCombo.item(1);
    buildCombo.text("Один-Один");

    buildCombo.item(2);
    buildCombo.text("Два-Два");

    buildCombo.item(3);
    buildCombo.text("Три-Три");

    // Вариант с добавление объекта и его модификацией ПОСЛЕ инициализации формы диалога
    dfTest = dialog.addField(types::ENUM);

    // Инициализируем форму диалога
    dialog.doInit();

    // Модифицируем содержимое
    fcbc = dfTest.fieldControl();

    fcbc.add("Один");
    fcbc.add("Два");
    fcbc.add("Три");

    isOk = dialog.run();

}