Не могу понять в чем ошибка???

[Sada]

Доброго всем времени суток, уважаемые коллеги.

есть вот такой кусок кода:

PHP Code:

   Query                                 q = new Query();
    QueryBuildDataSource        ds,ds2,ds3;
    queryRun                            qr;
    ;

    ds = q.addDataSource(tablenum(InventTrans));
    ds.addSelectionField(fieldnum(InventTrans,TransType));
    ds.addSelectionField(fieldnum(InventTrans,StatusIssue));
    ds.addSelectionField(fieldnum(InventTrans,DateStatus));
    ds.addSelectionField(fieldnum(InventTrans,ItemId));
    ds.addSelectionField(fieldnum(InventTrans,InventTransId));
    ds.addSelectionField(fieldnum(InventTrans,Qty));
    ds.addSelectionField(fieldnum(InventTrans,CustVendAC));
    s= "((inventTrans.StatusIssue == statusIssue::Sold || inventTrans.StatusReceipt == statusReceipt::Purchased))";
    q.dataSourceTable(TableNum(InventTrans)).addRange(FieldNum(InventTrans,recId)).value(s);
    ds.addRange(fieldNum(InventTrans, DateStatus)).value(sysQuery::range(PlanDateFrom, PlanDateTo));
    ds.addRange(fieldNum(InventTrans, TransType)).value(QueryValue(InventTransType::Sales));

    ds.orderMode(OrderMode::OrderBy);
    ds.addSortField(fieldnum(InventTrans, ItemId));
////////////////////////////
    ds2 = ds.addDataSource(tableNum(CustInvoiceTrans));
    ds2.addSelectionField(fieldnum(CustInvoiceTrans,InventTransId));
    ds2.addSelectionField(fieldnum(CustInvoiceTrans,Scrap));
    ds2.addSelectionField(fieldnum(CustInvoiceTrans,SalesPrice));
    ds2.addSelectionField(fieldnum(CustInvoiceTrans,Qty));
    ds2.addSelectionField(fieldnum(CustInvoiceTrans,LineAmount));
    ds2.addSelectionField(fieldnum(CustInvoiceTrans,TaxAmount));
    ds2.joinMode(JoinMode::InnerJoin);
    ds2.fetchMode(0);
    ds2.addLink(fieldNum(InventTrans,InventTransId),fieldNum  (CustInvoiceTrans,InventTransId));


////////////////////////////
    ds3 = ds.addDataSource(tablenum(CustTable));
    ds3.relations(true);
    ds3.joinMode(JoinMode::InnerJoin);
    ds3.fetchMode(0);

    ds3.addSelectionField(fieldnum(CustTable,Name));
    ds3.addSelectionField(fieldnum(CustTable,Agent));
    qr = new QueryRun(q);
    while (qr.next())
    {
     обработка данных..
    } 


на эту конструкцию мне Аксапта выдает "Ошибка расширенного диапазона запроса: inventTrans.StatusIssue не является корректной парой datasource.field рядом с 30
"
Подскадите плиз, что бы это значило. ошибка появляется на строке while (qr.next())....

C Уважением - Sada...

[TasmanianDevil]

Обычный бред Аксапты на очевидную ошибку
Все Range.Value - строки , т.е. надо написать s="Продано,Куплено"

[Sada]

тоесть нада вот это исправить
s= "((inventTrans.StatusIssue == statusIssue::Sold || inventTrans.StatusReceipt == statusReceipt::Purchased))";
q.dataSourceTable(TableNum(InventTrans)).addRange(FieldNum(InventTrans,recId)).value(s);
но на ЧТО?(попробовал не получилось...)

[TasmanianDevil]

Quote:

Originally Posted by Sada

тоесть нада вот это исправить
s= "((inventTrans.StatusIssue == statusIssue::Sold || inventTrans.StatusReceipt == statusReceipt::Purchased))";
q.dataSourceTable(TableNum(InventTrans)).addRange(FieldNum(InventTrans,recId)).value(s);
но на ЧТО?(попробовал не получилось...)

прошу прощения, не разобрался - Вы в фильтре хотите наложить ограничения на два поля , а не на одно
Скобочки одинарные, OR и просто имена полей не помогают ?

[Sada]

Quote:

Originally Posted by TasmanianDevil

прошу прощения, не разобрался - Вы в фильтре накладываете ограничения на два поля , а не на одно
В любом случае в значение фильтра по полю имеющему перечислимы тип - есть строка, и пихать туда надо именно строковое значение соответствующего числового значения перечислимого типа

да на два, и мне именно нада чтоб был OR...

[Sada]

Хелп...

[AndyD]

Во-первых, добавьте имя датасоурса

    ds = q.addDataSource(tablenum(InventTrans), "InventTrans");

Во-вторых, добавьте скобки

s= "((inventTrans.StatusIssue == statusIssue::Sold) || " +
    "(inventTrans.StatusReceipt == statusReceipt::Purchased))";

В-третьих, TransType устанавливайте так

ds.addRange(fieldNum(InventTrans, TransType)).
    value(int2str(InventTransType::Sales));

или так

ds.addRange(fieldNum(InventTrans, TransType)).
    value("(InventTrans.TransType == InventTransType::Sales)");

[AndyD]

Пардон, то, что в-третьих можно не делать

[Sada]

2AndyD
Спасибо огромное, теперь буду знать!!!Все заработало