Список методов таблицы

[DSPIC]

Думаю, примерно так:

static void classMethodInfo(Args _args)
{
    SysDictClass    sysDictClass;
    DictMethod      dictMethod;
    counter         methodCount, varCount;
    str             parmsStr;
    ;

    sysDictClass = new SysDictClass(classnum(RunBaseBatch));

    setPrefix(sysDictClass.name());

    methodCount = sysDictClass.objectMethodCnt();

    while (methodCount)
    {
        dictMethod = sysDictClass.objectMethodObject(methodCount);

        if (dictMethod)
        {
            parmsStr = '';

            for (varCount = dictMethod.parameterCnt(); varCount >= 1; varCount --)
            {
                parmsStr += strFmt("%1 %2, ", dictMethod.parameterType(varCount), dictMethod.parameterName(varCount));
            }

            parmsStr = strdel(parmsStr, strlen(parmsStr) - 1, 2);

            info (strFmt ("%1 (%2)", dictMethod.name(), parmsStr));
        }

        methodCount --;
    }
}

[lev]

Цитата:

Сообщение от DSPIC

Думаю, примерно так:

static void classMethodInfo(Args _args)
{
    SysDictClass    sysDictClass;
    DictMethod      dictMethod;
    counter         methodCount, varCount;
    str             parmsStr;
    ;

    sysDictClass = new SysDictClass(classnum(RunBaseBatch));

    setPrefix(sysDictClass.name());

    methodCount = sysDictClass.objectMethodCnt();

    while (methodCount)
    {
        dictMethod = sysDictClass.objectMethodObject(methodCount);

        if (dictMethod)
        {
            parmsStr = '';

            for (varCount = dictMethod.parameterCnt(); varCount >= 1; varCount --)
            {
                parmsStr += strFmt("%1 %2, ", dictMethod.parameterType(varCount), dictMethod.parameterName(varCount));
            }

            parmsStr = strdel(parmsStr, strlen(parmsStr) - 1, 2);

            info (strFmt ("%1 (%2)", dictMethod.name(), parmsStr));
        }

        methodCount --;
    }
}

Что бы народ не путался.
Изначально был вопрос про таблицы, для них нужно использовать SysDictTable, а не SysDictClass.

[DSPIC]

Цитата:

Сообщение от lev

Что бы народ не путался.
Изначально был вопрос про таблицы, для них нужно использовать SysDictTable, а не SysDictClass.

BINGO!
Для таблиц заменить SysDictClass на SysDictTable и classNum() на tablenum().
Всё остальное - 1:1

[SRF]

Цитата:

Сообщение от DSPIC

Думаю, примерно так:

static void classMethodInfo(Args _args)
{
    SysDictClass    sysDictClass;
    DictMethod      dictMethod;
    counter         methodCount, varCount;
    str             parmsStr;
    ;
 
    sysDictClass = new SysDictClass(classnum(RunBaseBatch));
 
    setPrefix(sysDictClass.name());
 
    methodCount = sysDictClass.objectMethodCnt();
 
    while (methodCount)
    {
        dictMethod = sysDictClass.objectMethodObject(methodCount);
 
        if (dictMethod)
        {
            parmsStr = '';
 
            for (varCount = dictMethod.parameterCnt(); varCount >= 1; varCount --)
            {
                parmsStr += strFmt("%1 %2, ", dictMethod.parameterType(varCount), dictMethod.parameterName(varCount));
            }
 
            parmsStr = strdel(parmsStr, strlen(parmsStr) - 1, 2);
 
            info (strFmt ("%1 (%2)", dictMethod.name(), parmsStr));
        }
 
        methodCount --;
    }
}

Небольшое дополнение :
1. данный код не учитывает статических методов, дополнил job DSPIC, чтобы статические методы учитывались

static void classMethodInfo(Args _args)
{
    SysDictClass    sysDictClass;
    DictMethod      dictMethod;
    counter         methodCount, varCount;
    str             parmsStr;
    ;
    sysDictClass = new SysDictClass(classnum(SysDictClass));
    setPrefix(sysDictClass.name());
    methodCount = sysDictClass.objectMethodCnt();
    while (methodCount)
    {
        dictMethod = sysDictClass.objectMethodObject(methodCount);
        if (dictMethod)
        {
            parmsStr = '';
            for (varCount = dictMethod.parameterCnt(); varCount >= 1; varCount --)
            {
                parmsStr += strFmt("%1 %2, ", dictMethod.parameterType(varCount), dictMethod.parameterName(varCount));
            }
            parmsStr = strdel(parmsStr, strlen(parmsStr) - 1, 2);
            info (strFmt ("%1 (%2)", dictMethod.name(), parmsStr));
        }
        methodCount --;
    }
 //SRF -->
    methodCount = sysDictClass.staticMethodCnt();
    while (methodCount)
    {
        dictMethod = sysDictClass.staticMethodObject(methodCount);
        if (dictMethod)
        {
            parmsStr = '';
            for (varCount = dictMethod.parameterCnt(); varCount >= 1; varCount --)
            {
                parmsStr += strFmt("%1 %2, ", dictMethod.parameterType(varCount), dictMethod.parameterName(varCount));
            }
            parmsStr = strdel(parmsStr, strlen(parmsStr) - 1, 2);
            info (strFmt ("%1 (%2)", dictMethod.name(), parmsStr));
        }
        methodCount --;
    }
//SRF <--
}

2. Данный код не работает в AX 3.0 SP2(он просто не компилируется, поскольку у dictMethod отсутсвует метод parameterName)

OFFTOPIC : вообще если нужны только списки методов без параметров то для DAX 4.0(также для других версий) можно использовать static-методы класса sysPickList, например, чтобы получить список методов таблицы в DAX 4.0 достаточно вызвать ниже приведенный код

sysPickList::fillTablesMethodsMap(tableId)

[s_s_a]

Ну все нахрен этот встроенный отчетник Буду теперь через нормальные ситстемы печатать

[lev]

Цитата:

Сообщение от s_s_a

Ну все нахрен этот встроенный отчетник Буду теперь через нормальные ситстемы печатать

Что за "встроенный отчетник"? Какие "нормальные системы"?

[s_s_a]

А как в Аксапте сделать неполомав рук сложную форму? ТТН, например?

Вот я и озадачился. Прикрутил StimulSoft Report. И через BusinessConnector.Net пхаю в него данные. Работает быстро. А уж разработка самих форм ваааще песня!

Первая версия собранных мной костылей требует некоторой ручной работы. Вот решил доавтоматизировать чуток

[lev]

Цитата:

Сообщение от s_s_a

А как в Аксапте сделать неполомав рук сложную форму? ТТН, например?

Вот я и озадачился. Прикрутил StimulSoft Report. И через BusinessConnector.Net пхаю в него данные. Работает быстро. А уж разработка самих форм ваааще песня!

Первая версия собранных мной костылей требует некоторой ручной работы. Вот решил доавтоматизировать чуток

Что то я не совсем понял... Тема вроде про то, как получить список методов таблицы
... Причем тут репорты аксаптовские??
Про то что сделать в аксаптовском репорте сложную печатную форму - это мука, полностью согласен!

[s_s_a]

Получить данные из АХ сторонее приложение (в данном случае сторонний Генератор Отчетов) может и через базу напрямую, наверное. Но ведь таблицы могут выводить и какие-то расчитанные налету данные через методы. Вот, чтоб руками их не указывать, а получать список и использовать как поля в отчетнике, мне и понадобилась ваша помощь.

Если кто заинтересуется, могу подробней расписать...

[petergunn]

Цитата:

...
for (varCount = dictMethod.parameterCnt(); varCount >= 1; varCount --)
{
    parmsStr += strFmt("%1 %2, ", dictMethod.parameterType(varCount), dictMethod.parameterName(varCount));
}

Не будет ли отображаемый список параметров метода при таком цикле идти в обратном порядке? или в данном контексте считаем что это не важно?

Добавлю своих 5 копеек для DAX 4.0:

static void jbTableMethodList(Args _args)
{
    void tableMethodList( TableId _tableId, boolean _isStatic = false )
    {
        DictTable       dictTable = new DictTable( _tableId ) ;
        DictMethod      dictMethod      ;
        
        Counter         methodCount     ;
        Counter         methodIdx       ;
        Counter         varIdx          ;
        
        str             methodNameTxt   ;
        str             varListTxt      ;
        ;

        if( !dictTable )
            return ;

        setPrefix( strfmt( "%1 - %2 methods", dictTable.name(), _isStatic ? 'static' : 'instance' ) ) ;
        methodCount = _isStatic ? dictTable.staticMethodCnt() : dictTable.objectMethodCnt() ;
        for( methodIdx=1; methodIdx<=methodCount; methodIdx++ )
        {
            dictMethod = _isStatic ? dictTable.staticMethodObject( methodIdx ) : dictTable.objectMethodObject( methodIdx ) ;
            methodNameTxt = dictMethod.runMode() == ClassRunMode::Called ? '' : strfmt( "%1 ", dictMethod.runMode() ) ;
            methodNameTxt += strfmt( "%1 %2", extendedTypeId2DisplayName( dictMethod.returnType(), dictMethod.returnId() ), dictMethod.name() ) ;
            
            varListTxt = '' ;
            for( varIdx=1; varIdx<=dictMethod.parameterCnt(); varIdx++ )
            {
                varListTxt += strfmt( "%1 %2%3, ",  extendedTypeId2DisplayName( dictMethod.parameterType( varIdx ), dictMethod.parameterId( varIdx ) ),
                                                    dictMethod.parameterName( varIdx )    ,
                                                    dictMethod.parameterOptional( varIdx ) ? ' (optional)' : '' ) ;
            }
            info( strfmt( "%1(%2)", methodNameTxt, strdel( varListTxt, strlen( varListTxt ), -2 ) ) ) ;
        }
    }
    ;

    info( 'Dict reflection: DictTable & DictMethod' ) ;
    tableMethodList( tableNum( InventTable), false ) ;
    tableMethodList( tableNum( InventTable ), true ) ;
}