Группировка в лукапе

[greench]

День добрый всем, не знаю проскакивала ли подобная тема, по поиску не нашел.

У контрола формы, основанного на EDT, перекрыт метод lookup. Примерный код выглядит так:

public void lookup()
{
    Query                            query = new Query();
    QueryBuildDataSource    queryBuildDataSource;
    SysTableLookup             sysTableLookup;
    tableId                            tableId;
    fieldId                            fieldId;
    ;
    tableId        = tableNum(Table1);
    sysTableLookup = SysTableLookup::newParameters(tableId, this,false);
    fieldId         = fieldnum(Table1, Field1);
    sysTableLookup.addLookupfield(fieldId);
   
    queryBuildDataSource = query.addDataSource(tableId);

    queryBuildDataSource.addRange(fieldnum(Table1,     Field2)).value(SysQuery::value(RangeValue));
    queryBuildDataSource.addGroupByField(fieldnum(Table1,Field1));
   
    sysTableLookup.parmQuery(query);

    sysTableLookup.performFormLookup();

}

Значения Field1 в таблице, которая является источником данных для лукапа, не уникальные, поэтому по ним производится группировка. Все работает корректно. Но если мы попробуем сделать сортировку в выпадающем списке, то групппировка слетает.

Как с этим бороться, может кто подскажет?

[samolalex]

Насколько я знаю, в Axapta возможна либо группировка, либо сортировка (во всяком случае в 3-ей версии).
Если же вы хотите задать сортировку по группировочному полю, то, скорее всего, следует сделать так:

public void lookup()
{
    Query                            query = new Query();
    QueryBuildDataSource    queryBuildDataSource;
    SysTableLookup             sysTableLookup;
    tableId                            tableId;
    fieldId                            fieldId;
    ;
    tableId        = tableNum(Table1);
    sysTableLookup = SysTableLookup::newParameters(tableId, this,false);
    fieldId         = fieldnum(Table1, Field1);
    sysTableLookup.addLookupfield(fieldId);
   
    queryBuildDataSource = query.addDataSource(tableId);

    queryBuildDataSource.addRange(fieldnum(Table1,     Field2)).value(SysQuery::value(RangeValue));
    queryBuildDataSource.orderMode(orderMode::GroupBy);
    queryBuildDataSource.addSortField(fieldnum(Table1,     Field1), sortOrder::Ascending);
   
    sysTableLookup.parmQuery(query);

    sysTableLookup.performFormLookup();

}

[greench]

Точно, спасибо.

[sukhanchik]

Небольшое замечание. Если вдруг в лукапе потом захочется вывести поля, к которым нужно применить агрегатную функцию (Sum, Count и т.д.), то можно столкнуться с неприятным моментом, когда пропадает группировка.
Связано это с тем, что в рамках оптимизации исполнения запроса выбираются не все поля, а только те, что определены в лукапе (для которых был вызван метод addLookupField).
Соответственно, выполняется следующий код (\Classes\SysTableLookup\buildSelectionList):

        for (i = 1; i <= conlen(lookupItems); i++)
        {
            [fieldId, returnItem, method] = conpeek(lookupItems, i);
            queryBuildDataSource.addSelectionField(fieldId);
        }

И тут, как несложно заметить - метод addSelectionField вызывается без агрегатных функций. Соответственно, все наши Sum-ы пропадают и по этим полям начинает работать группировка (т.е. фактически, она слетает).

Лечится это простым условием:

    if (queryBuildDataSource.orderMode() == OrderMode::OrderBy) // Ограничение числа полей актуально только для выборки без группировок    
    {
        for (i = 1; i <= conlen(lookupItems); i++)
        {
            [fieldId, returnItem, method] = conpeek(lookupItems, i);
            queryBuildDataSource.addSelectionField(fieldId);
        }
    }

после чего суммирование начинает работать нормально.

Справедливо для всех версий (3.0 - 2009 RU5)

[vallys]

Добавлю, что в этом методе (\Classes\SysTableLookup\buildSelectionList) не корректно определяется наличие методов (проявляется как пустые значения дисплэй методов в лукапе):

    // Test that all are fields (no methods)
    for (i = 1; i <= conlen(lookupItems); i++)
    {
        [fieldId, returnItem, method] = conpeek(lookupItems, i);

        if (method)
        {
            return;
        }
    }

При выполнении строки

[fieldId, returnItem, method] = conpeek(lookupItems, i);

боулевская переменная method всегда принимает значение false независимо от значений (AX 2009 RU5).
Для исправления достаточно изменить тип локальной переменной method с boolean на str.

[Damn]

Цитата:

Сообщение от vallys

Добавлю, что в этом методе (\Classes\SysTableLookup\buildSelectionList) не корректно определяется наличие методов (проявляется как пустые значения дисплэй методов в лукапе):

    // Test that all are fields (no methods)
    for (i = 1; i <= conlen(lookupItems); i++)
    {
        [fieldId, returnItem, method] = conpeek(lookupItems, i);

        if (method)
        {
            return;
        }
    }

Почему-то в HFR8 (а также в Ax2012R3) тип переменной method изменили, но использовать её перестали. То есть при наличии display-методов в лукапе поля в нём всё равно оптимизируются и селектятся не все. Что сильно мешает в том случае когда отображаемый display-метод основан на полях, не выводящихся в лукап.
В Ax2009 были проблемы с лукапами, основанными на запросах с применением Union. Как раз метод \Classes\SysTableLookup\buildSelectionList портил всё. В Ax2012 вроде попытались исправить и учесть Union, но опять же не до конца. Если union состоит из двух одинаковых таблиц, то проблем нет. Но если к одной из таблиц в union приджойнена ещё какая-нибудь таблица (ExistsJoin например), то лукап перестаёт работать.

[S.Kuskov]

А не проще ли для такого лукапа сделать View?

[S.Kuskov]

Цитата:

Сообщение от Damn

при наличии display-методов в лукапе поля в нём всё равно оптимизируются и селектятся не все. Что сильно мешает в том случае когда отображаемый display-метод основан на полях, не выводящихся в лукап.

В sysTableLookup просится метод для явного добавления полей в выборку через queryBuildDataSource.addSelectionField(), но не отображающий их. Наверное не сложно такой костыль реализовать.

[Damn]

Цитата:

Сообщение от S.Kuskov

В sysTableLookup просится метод для явного добавления полей в выборку через queryBuildDataSource.addSelectionField(), но не отображающий их. Наверное не сложно такой костыль реализовать.

Да я чтоб сильно не мучиться просто вернул на место этот программный код из ранних версий :

    // Test that all are fields (no methods)
    for (i = 1; i <= conlen(lookupItems); i++)
    {
        [fieldId, returnItem, method] = conpeek(lookupItems, i);

        if (method)
        {
            return;
        }
    }

Для лукапов, содержащих display-методы, селектятся все поля и все довольны.
И для использования union в лукапах тоже класс SysTableLookup подкорректировал в нужных местах.