axforum blogs: FizzBuzz

[Blog bot]

Источник: http://axforum.info/forums/blog.php?b=358
==============

Навеяно статьей FizzBuzz, или почему программисты не умеют программировать

Цитата:

Напишите программу, которая выводит на экран числа от 1 до 100. При этом вместо чисел, кратных трем, программа должна выводить слово «Fizz», а вместо чисел, кратных пяти — слово «Buzz». Если число кратно и 3, и 5, то программа должна выводить слово «FizzBuzz»

#define.FIZZ(3)
#define.BUZZ(5)
static void FizzBuzzImpl(Args _args)
{
    int i;
    ;

    for (i = 1; i <=100; i++)
    {
        switch(true)
        {
            case ((i mod #FIZZ) == 0) && ((i mod #BUZZ) == 0):
                info(strfmt("FizzBuzz %1", i));
                break;
            case ((i mod #FIZZ) == 0):
                info(strfmt("Fizz (%1)", i));
                break;
            case ((i mod #BUZZ) == 0):
                info(strfmt("Buzz (%1)", i));
                break;
            default:
                info(strfmt("%1", i));
        }
    }
}

p.s. Кстати, switch(true) невероятно мощная конструкция, которую можно смело считать реализацией "Сопоставления с образцом"(pattern matching) в Х++.

[mazzy]

Цитата:

Сообщение от Blog bot

Навеяно статьей FizzBuzz, или почему программисты не умеют программировать

Если честно, то чудовищная реализация, на мой взгляд.
Избыточное вычисление mod и куча лишнего кода.

с точки зрения вычислений лучше уж так.

#define.FIZZ(3)
#define.BUZZ(5)
static void FizzBuzzImpl(Args _args)
{
    int i;
    str fizz;
    str buzz;
    ;

    for (i = 1; i <=100; i++)
    {
        fizz = ((i mod #FIZZ) == 0) ? "Fizz" : "";
        buzz = ((i mod #BUZZ) == 0) ? "Buzz" : "";
        if( fizz || buzz )
        {
            info(strfmt("%1%2 %3", fizz, buzz, i));
        }
    }
}

можно было бы отказаться и от переменных fizz, buzz. Но код стал бы менее читаемым.

[Lemming]

Хмм, что-то у меня не компилируется код, ругается на строчку "fizz = (i mod #FIZZ) == 0) ? "Fizz" : "";" - Типы операнда не совместимы с оператором

[mazzy]

а вот объектно-ориентированная многословная реализация, если не лень заводить класс в AOT. Но зато тело цикла не содержит деталей реализации - детали в классе.

class TestState
{
   boolean state;
   str description;
}
void new(int i, int num, int _description)
{
    state = i mod num;
    if( state )
        description = _description;
}
boolean getState()
{
    return state;
}
str getDescription()
{
    return description;
}
/////////////////////////////////////////
#define.FIZZ(3)
#define.BUZZ(5)
static void FizzBuzzImpl(Args _args)
{
    int i;
    TestState fizz, buzz;
    ;

    for (i = 1; i <=100; i++)
    {
        fizz = new TestState(i, #FIZZ, "Fizz");
        buzz = new TestState(i, #BUZZ, "Buzz");
        if( fizz.getState() || buzz.getState() )
        {
            info(strfmt("%1%2 %3", fizz.getDescription(), buzz.getDescription(), i));
        }
    }
}

вместо параметра num в методе new можно сделать пару классов-потомков
вместо простой конкатенации строк FizzBuzz можно сделать класс, который формирует вывод...

В любом случае, это будет лучше чудовищного switch.

[mazzy]

Цитата:

Сообщение от Lemming

Хмм, что-то у меня не компилируется код, ругается на строчку "fizz = (i mod #FIZZ) == 0) ? "Fizz" : "";" - Типы операнда не совместимы с оператором

ага. спасибо. скобку открывающую забыл.
надо fizz = ((i mod #FIZZ) == 0) ? "Fizz" : ""

просто я пока без акспты

[mazzy]

кстати. в исходной задаче нужно было выводить все числа.
в процедурном коде можно убрать if.
а объектно-ориентированный код становится еще короче.

class TestState
{
   str description;
}
void new(boolean _state, int _description)
{
    if( _state )
        description = _description;
}
str getDescription()
{
    return description;
}
/////////////////////////////////////////
#define.FIZZ(3)
#define.BUZZ(5)
static void FizzBuzzImpl(Args _args)
{
    int i;
    TestState fizz, buzz;
    ;

    for (i = 1; i <=100; i++)
    {
        fizz = new TestState(((i mod #FIZZ) == 0), "Fizz");
        buzz = new TestState(((i mod #BUZZ) == 0), "Buzz");
        info(strfmt("%1%2 %3", fizz.getDescription(), buzz.getDescription(), i));
    }
}

[Lemming]

Все, я сдаюсь, тут опять две ошибки компиляции, одна в new, я ее вроде пофиксил, хотя не факт что правильно, т.к. не до конца понимаю задумку кода, а вторая в запускающем Job'е, снова путаница int/str...mazzy может все-таки не "на бумажке", а то очень интересно проверить результат, а оно работать не хочет... Прошу прощения, не сразу прочел что вы без аксы.

upd: Джобик из второго поста запустил, да, работает. Спасибо!

[mazzy]

можно сократить число внутренних переменных в необъектной реализации.
правда не уверен, что код станет быстрее из-за дополнительной сборки мусора.

#define.FIZZ(3)
#define.BUZZ(5)
static void FizzBuzzImpl(Args _args)
{
    int i;
    str state;
    ;

    for (i = 1; i <=100; i++)
    {
        state = "";
        if ((i mod #FIZZ) == 0) { state += "Fizz"; }
        if ((i mod #BUZZ) == 0) { state += "Buzz"; }
        info(strfmt("%1 %2", state, i));
    }
}

switch - зло как правило. Поскольку по мере развития программы число вариантов в switch может меняться. А найти все switch - на редкость нетривиальное дело.

Но как пример использования неконстант в case - очень даже ничего.

[Lemming]

Цитата:

Сообщение от mazzy

switch - зло как правило. Поскольку по мере развития программы число вариантов в switch может меняться. А найти все switch - на редкость нетривиальное дело.

Не очень понял что именно сложно найти, вроде все ветви в одном месте, хотя когда он становится большим, читать такой код не очень приятно, согласен.

[mazzy]

Цитата:

Сообщение от Lemming

Не очень понял что именно сложно найти

сложно найти все switch, которые относятся к данному случаю (в Аксапте к данному enum)

собственно, стоит почитать Страустрапа и других отцов объектно-ориентированного программирования по поводу switch.

[gl00mie]

Цитата:

Сообщение от mazzy

сложно найти все switch, которые относятся к данному случаю (в Аксапте к данному enum)

Как раз для enum'ов switch очень даже прекрасно подходит, если использовать простые правила касаемо default:

• всегда использовать блок default;
• либо явно предусматривать в нем логику для "всех остальных" случаев, либо ставить там заглушку, чтобы код сразу валился при неизвестных на момент разработки значениях

Например:

switch (noYesValue)
{
    case NoYes::No :
        // ...
        break;
    case NoYes::Yes :
        // ...
        break;
    default :
        throw error(Error::unsupportedEnumValue(noYesValue));
}

Здесь Error::unsupportedEnumValue() - метод вида:

public static LabelType unsupportedEnumValue(anytype _enumValue)
{
    return strfmt(@"Значение %1 (%2) не поддерживается", _enumValue, any2int(_enumValue));
}

[mazzy]

Цитата:

Сообщение от gl00mie

Как раз для enum'ов switch очень даже прекрасно подходит

подходит.
но так мы получаем run-time error. на этапе компиляции ошибка не диагностируется.
в Аксапте в чем-то помогают перекрестные ссылки, конечно...

[S.Kuskov]

Цитата:

Сообщение от Blog bot

switch(true) невероятно мощная конструкция, которую можно смело считать реализацией "Сопоставления с образцом"(pattern matching) в Х++.

Только нужно понимать, что образцы в этом случае должны быть взаимоисключающими. Т.е. в каждый конкретный момент истинным должно быть только одно условие, иначе логика выполнения может стать отличной от ожидаемой.
Из-за этого добавление нового условия к уже имеющимся может потребовать изменить и все остальные.

Ещё как-то встречал извращенцев умельцев играющих на опускании break в определённых ветках case. Уследить за полётом мысли таких "авторов" бывает очень сложно.

P.S.: Для решения задачи из первого поста подходит паттерн цепочка декораторов

[Lemming]

Цитата:

Сообщение от S.Kuskov

Ещё как-то встречал извращенцев умельцев играющих на опускании break в определённых ветках case. Уследить за полётом мысли таких "авторов" бывает очень сложно.

Например code conventions в java(во всяком случае я там про это прочел) предлагает помечать пропуски break'ов комментарием fall-through, что бы программисты читающие код были предупреждены что это не ошибка, а задумка.

[Lemming]

Цитата:

Сообщение от mazzy

подходит.
но так мы получаем run-time error. на этапе компиляции ошибка не диагностируется.
в Аксапте в чем-то помогают перекрестные ссылки, конечно...

Кстати, по поводу run-time error, возможно в некоторых случаях это не так уж и страшно. Во всяком случае если снабдить ошибку человеческим описанием, то сразу станет ясно что пользователь должен обратиться в службу поддержки. Более того, в отличии от других сред run-time error в аксапте не крешит всю систему, а перехватывается ядром, что сильно отличает ее от традиционных платформ для разработки софта.

Вспомнилось в legacy из 2.5, в которой не было полноценных абстрактных классов, Датские программисты похожим образом имитировали абстрактные методы, когда в теле метода принудительно выбрасывали исключение с сообщением что "Метод должен быть перекрыт". И ничего, как-то наверное жили со всем этим.

[fed]

Хотя я уже лет 15 не программирую на C/C++, мне конструкции вида (i mod #FIZZ) == 0 режут глаз.
Я бы написал !(i mod #FIZZ). Я понимаю что это вопрос стиля, вкуса и вообще для интерпретируемого языка разница в производительности отсутствует. Но глаз все равно режет...

[Stitch_MS]

Можно и так (кода больше, но резь в глазах уменьшится )

class Number
{
    int number;
    public void new(int _number)
    {
        number = _number;
    }
    public boolean isDivisibleBy(int _denominator)
    {
        return (number mod _denominator) == 0;
    }
}
static void testFizzBuzz(Args _args)
{
    str fullWord;
    Number number;
    int i;
    for (i = 1; i <= 100; i++)
    {
        fullWord = '';
 
        number = new Number(i);
 
        if (number.isDivisibleBy(3))
        {
            fullWord += "Fizz";
        }
 
        if (number.isDivisibleBy(5))
        {
            fullWord += "Buzz";
        }        
 
        if (fullWord != '')
        {
            info(strFmt("%1 %2", i, fullWord));
        }
    }
}

[pedrozzz]

Любители тернарных операторов видят это, наверное, так

#define.FIZZ(3)
#define.BUZZ(5)
static void FizzBuzzImpl(Args _args)
{
    int i;
    ;

    for (i = 1; i <= 100; i++)
    {
        info(! (i mod (#FIZZ * #BUZZ)) ? "FizzBuzz"
                                       : ! (i mod #FIZZ) ? "Fizz"
                                                         : ! (i mod #BUZZ) ? "Buzz"
                                                                           : int2str(i));

    }
}

[Bergman]

По-моему самое простое это:

for (i = 1; i <=100; i++)
            {

                if (i % 3 == 0 && i % 5 == 0)
                    Console.WriteLine("BuzzFuzz");
                else if ( i %3 ==0)
                    Console.WriteLine("Fuzz");
                else if(i%5 ==0)
                
                 Console.WriteLine("Buzz");
                else 
                    Console.WriteLine("{0}", i);
                
                }

[mazzy]

Цитата:

Сообщение от Stitch_MS

Можно и так (кода больше, но резь в глазах уменьшится )

Цитата:

Сообщение от pedrozzz

Любители тернарных операторов видят это, наверное, так

Цитата:

Сообщение от Bergman

По-моему самое простое это:

Не, ребят.
1.
Вы занимаетесь внешним видом, а не сутью.
В ваших примерах (как и в изначальном) нахождение остатка от деления вычисляется несколько раз (до 4 вместо необходмых 2 вычислений).

Представьте, что в реальной жизни это будет не нахождение остатка от деления, а вычисление остатка на некую дату на некоем складе и отдельно на складе пополнения. Вы и там тоже будете запускать процедуру расчета остатков лишние разы?

2.
Чем плох if else if... тем что выражение внутри if вычисляется несколько раз.
условие внутри switch всегда вычисляется только один раз. Именно для этого (ну, кроме формы записи) и вводился switch в процедурные языки.
если в switch условие вычисляется один раз, а в case константы... то можно добиться существенной оптимизации. А не только внешнего вида.

в исходном примере суть switch вывернута наизнанку - условие константа, а в case - выражения (вдобавок с избыточным количеством).

Возврат к if else if... это возврат.

примерно так.
удивительно, что об этом приходится писать.