Сравнение Query.pack()

[kit22]

Здравствуйте!
Есть таблица, где есть поле типа контейнер.
Туда я пишу query.pack().

Мне надо узнать, есть ли уже в этом поле данный запрос. Как это сделать?

void compareFunc(container _packedQuery)
{
   ;
   for (i = 1; i<= conpeek(this.ContainerField); i++)
  {
     if (conPeek(this.containerField, i) == conpeek(_packedQuery, 1))
     {
         info("");
     }
  }
}

Пробовал так, но падает что типы сравнения несовместимы.

[Cardagant]

Добрый вечер!

myQueryTable - таблица с полем типа контейнер.

У меня следующий джоб сравнивает верно:

static void Job30(Args _args)
{
    // Таблица, содержащая контейнер запроса AssetTable
    QueryTable  myQueryTable;

    // AssetTable - Эквивалентны
    container   packedQuery = new Query(querystr(AssetTable)).pack();

    // AxdAddress - неэквивалентны
    // container   packedQuery = new Query(querystr(AxdAddress)).pack();
    ;

    // Наполнил исходными данными
    /*
    QueryTable.QueryCon = (new Query(querystr(AssetTable)).pack());
    QueryTable.write();
    */

    select firstonly myQueryTable;

    // Сравниваю
    if (myQueryTable.QueryCon == packedQuery)
    {
        info("Equal");
    }
}

[kit22]

Добрый! Дело в том, что у меня в этом поле может храниться много query.pack(). Заполнение поля идет следующим образом

 this.containerField += query.pack()

То есть мне надо узнать, есть ли в этом поле уже данный запрос, а в поле, например, хранится уже 4 query.pack() и пришел новый query.pack(). И мне не надо записывать query.pack() в это поле, если он уже есть там.

[Cardagant]

Цитата:

Сообщение от kit22

Добрый! Дело в том, что у меня в этом поле может храниться много query.pack(). Заполнение поля идет следующим образом

 this.containerField += query.pack()

То есть мне надо узнать, есть ли в этом поле уже данный запрос, а в поле, например, хранится уже 4 query.pack() и пришел новый query.pack(). И мне не надо записывать query.pack() в это поле, если он уже есть там.

Для проверки данного запроса на наличие в поле таблицы придумал вот такой способ:

static void EqualQueries(Args _args)
{
    // Таблица, содержащая контейнер запроса AssetTable
    QueryTable  myQueryTable;
    container   containerField;

    // AssetTable - Эквивалентны
    container   packedQuery = new Query(querystr(AssetTable)).pack();

    // AxdAddress - неэквивалентны
    // container   packedQuery = new Query(querystr(AxdAddress)).pack();
    ;

    // Наполнил исходными данными
    /*
    containerField += (new Query(querystr(AssetTable))      .pack());
    containerField += (new Query(querystr(AssetBudgetModel)).pack());
    containerField += (new Query(querystr(AssetProposal))   .pack());
    containerField += (new Query(querystr(AxdExpense))      .pack());

    myQueryTable.QueryCon = containerField;
    myQueryTable.write();
    */

    select firstonly myQueryTable;
    containerField = myQueryTable.QueryCon;

    // Сравниваю
    while (conlen(containerField))
    {
        if (new Query(containerField).pack() == packedQuery)
        {
            info("Equal");
        }

        containerField = condel(containerField, 1, 1);
    }
}

[Sada]

юзайте это

for (i = 1; i <= conlen(con); i++)
{
variable = conpeek(con, i);
}

[Cardagant]

Цитата:

Сообщение от Sada

юзайте это

for (i = 1; i <= conlen(con); i++)
{
variable = conpeek(con, i);
}

Пробовал, для данного случая вылетает ошибка несовместимости типов присвоения:
"Неправильные типы аргументов в операции присвоения значения переменной."

[kit22]

Спасибо! Действительно работает, хотя и немного искусственно Но других способов не нашел. Странно, что conpeek падает на сравнение. Видимо, дело в том, что query.pack() пакуется как контейнер с BLOB данными.

[Cardagant]

Цитата:

Сообщение от kit22

Спасибо! Действительно работает, хотя и немного искусственно Но других способов не нашел. Странно, что conpeek падает на сравнение. Видимо, дело в том, что query.pack() пакуется как контейнер с BLOB данными.

Соглашусь, что вполне может быть связано с этим.
Может кто-то предложит более красивый вариант решения данной задачи.
Рад помочь!

[Мартынов Дмитрий]

Цитата:

Сообщение от Cardagant

Соглашусь, что вполне может быть связано с этим.
Может кто-то предложит более красивый вариант решения данной задачи.
Рад помочь!

А как вообще сравнить два query ?
Напрашивается один простой способ:

if (
query1.dataSourceNo(1).toString() == query2.dataSourceNo(1).toString();
)

Если это сработает - то дальше очевидно распаковываем нужный контейнер в query и сравнить два query.