отключение сортировки при lookup

[altap]

Вообщем на досуге посидел, надеюсь, что поможет.
В классе SysTableLookup модифицировал метод buildGrid к такому виду:

protected FormBuildGridControl buildGrid(FormBuildGridControl _formBuildGridControl,
                                         FormBuildDataSource  _formBuildDataSource,
                                         Form                   form) //передаем форму в метод для поиска ее ноды
{
    FormBuildControl                formBuildControl;
    Object                          obj;
    boolean                         returnItem;
    boolean                         method;
    int                             fieldId;
    int                             i, j;
    //-->
    TreeNode                        gridNode, controlNode, methodsNode;
    MemberFunction                  newMethod;
    str                             source;
    TreeNodeIterator                iterator;
    //<--
    ;

    for (i = 1; i <= conlen(lookupItems); i++)
    {
        [fieldId, returnItem, method] = conpeek(lookupItems, i);

        if (!method)
        {
            formBuildControl = _formBuildGridControl.addDataField(_formBuildDataSource.id(), fieldId);

            if (i == 1 || returnItem)
            {
                controlIdx = formBuildControl.id();
                lookupField = fieldId;
            }

            obj = formBuildControl;

            if (labels[i])
            {
                obj = formBuildControl;
                obj.label(labels[i]);
            }

            //Дойдем до созданного контрола
            gridNode = form.AOTfindChild('Designs');
            gridNode = gridNode.AOTfindChild('Design');
            gridNode = gridNode.AOTfirstChild();

            iterator = gridNode.AOTiterator();
            controlNode = iterator.next();
            while (controlNode)
            {
                If (controlNode.AOTname() == obj.name()) break;
                controlNode = iterator.next();
            }

            //Перекроем метод sort
            methodsNode = controlNode.AOTfindChild('Methods');
            methodsNode.AOTadd('sort');
            newMethod   = methodsNode.aotfindChild('sort');

            source      = 'public int sort(SortOrder _sortDirection) ' +
                            '{ ' +
                            '    ; ' +
                            '    return 0; ' +
                            '}';

            newMethod.AOTsetSource(source, false);
            //Откомпилируем новый метод
            newMethod.AOTcompile(1);
        }
    }

    return _formBuildGridControl;
}

единственное, что не смог победить - это при компиляции метода выскакивает окошко сообщений компилятора...
Вдохновило это

[wojzeh]

Цитата:

Сообщение от altap

Вообщем на досуге посидел, надеюсь, что поможет.
В классе SysTableLookup модифицировал метод buildGrid к такому виду:

гут. аккурат то, что требовалось. как-то совсем забыл про возможность добраться до свежесозданного элемента формы через AOT. главное, чтоб не тормозило шибко при работе нескольких пользователей.

чуток переделал код:

в описании переменных добавил:

   //-->
TreeNode                        gridNode, controlNode, methodsNode;
MemberFunction                  newMethod;
str                             source = 'public int sort(SortOrder _sortDirection){; return 0;}';
TreeNodeIterator                iterator;
//<--

в конце стандартного метода buildGrid добавил:
...

    //-->
    gridNode = _form.AOTfindChild('Designs');
    gridNode = gridNode.AOTfindChild('Design');
    gridNode = gridNode.AOTfirstChild();
    iterator = gridNode.AOTiterator();
    controlNode = iterator.next(); //methods of the grid control!
    controlNode = iterator.next();
    for (i = 1; i <= conlen(lookupItems); i++)
    {
            methodsNode = controlNode.AOTfindChild('Methods');
            newMethod    = methodsNode.AOTadd('sort');
            newMethod.AOTsetSource(source, false);
            newMethod.AOTcompile(1);
            controlNode = iterator.next();
    }
    //<--
    return _formBuildGridControl;
}

большое спасибо!

[wojzeh]

Цитата:

Сообщение от altap

единственное, что не смог победить - это при компиляции метода выскакивает окошко сообщений компилятора...

я сделал вот так:

...
    this.setCompilerWarningsOff();
    for (i = 1; i <= conlen(lookupItems); i++)
    {
            //override sort method
            methodsNode = controlNode.AOTfindChild('Methods');
            newMethod   = methodsNode.AOTadd('sort');
            newMethod.AOTsetSource(source, false);
            //compile the method
            newMethod.AOTcompile();
            controlNode = iterator.next();
    }
    this.setCompilerWarningsOn();
...

а отключал-включал не мудрствуя лукаво:

class SysTableLookupWithoutSort extends SysTableLookup
{
    SysCompilerTarget   target;
}

public void setCompilerWarningsOff()
{
    ;
    target = SysUserInfo::compilerTarget();
    SysUserInfo::compilerTarget(sysCompilerTarget::MessageWindow);
    SysCompilerOutput::setCompilerTarget(sysCompilerTarget::MessageWindow);
    SysCompilerOutput::updateParm();
}

public void setCompilerWarningsOn()
{
    ;
    SysUserInfo::compilerTarget(target);
    SysCompilerOutput::setCompilerTarget(target);
    SysCompilerOutput::updateParm();
}