[belugin]

1. Декларируем для какого класса объектов применим провайдер - при помощи SysClassNameAttribute (например, у отчетов по ОС общий предок, можно сказать, что для всех отчетов по ОС брать шаблоны, допустим, из папки)
2. Если надо вычислять условия применения в рантайме, имплементим SysIConditionalExtension и перекрываем isApplicableTo
3. Если для данного объекта есть несколько расширений, то провайдер для более конкретного класса предпочитается провайдеру для более общего, провайдет который реализует SysIConditionalExtension предпочитается тому, который не имплементит.

см XML документацию для SysGeneralizableExtensionAppFactory

Тестовый провайдер обслуживает все объекты:

[SysClassNameAttribute(classStr(Object))]
class AOTResourceTemplateProviderTestHelper_RU extends AOTResourceTemplateProvider_RU
implements SysIConditionalExtension
{

Но применим только если мы
1. выполняем юнит тест
2. Включили в тесте параметр

 /// <summary>
    /// Returns whether an extension can be applied in current conditions
    /// </summary>
    /// <param name="_value">
    /// Parameter that specifies extension context
    /// </param>
    /// <returns>
    /// true, if the extension can be applied; otherwise, false.
    /// </returns>
    boolean isApplicableTo(AnyType _value)
    {
        #localMacro.runningUnitTestsClient
        '(C)\\Classes\\SysTestSuite\\run'
        #endmacro
        #localMacro.runningUnitTestsServer
        '(s)\\Classes\\SysTestSuite\\run'
        #endmacro

        container callStack;

        if (_value && typeOf(_value) == Types::Class)
        {
            callStack = xSession::xppCallStack();

            if (conFind(callStack, #runningUnitTestsClient) ||
                conFind(callStack, #runningUnitTestsServer))
            {
                return AOTResourceTemplateProviderTestHelper_RU::applicable();
            }
        }

        return false;
    }
public static boolean applicable(boolean _applicable = true)
    {
        SysGlobalCache cache = classfactory.globalCache();
        boolean        applicable;

        if (prmisDefault(_applicable))
        {
            if (cache.isSet(#CacheScopeKeyApplicable))
            {
                applicable = cache.get(#CacheScopeKeyApplicable);
            }
            else
            {
                applicable = true;
            }
        }
        else
        {
            applicable = _applicable;
            cache.set(#CacheScopeKeyApplicable, applicable);
        }

        return applicable;
    }