static void CreateQRCode(Args _args)
{    
    Microsoft.Dynamics.QRCode.Encoder   encoder;
    System.Drawing.Bitmap               bitmap;
    
    str url = "http://axforum.info/";
    str fileName = @"C:\Temp\QrCode.jpg";
    ;
    
    encoder = new Microsoft.Dynamics.QRCode.Encoder();
    
    bitmap = encoder.Encode(url);
    bitmap.Save(fileName, System.Drawing.Imaging.ImageFormat::get_Jpeg());
}

//Настройка журнала базы данных для таблицы
static void DatabaseLogSetup(Args _args)
{
    TableName   tableName = 'CustTable'; //TODO: 1. Указать название таблицы

    void createDatabaseLog(TableName _tableName, DatabaseLogType _logType, boolean _infoLog = true)
    {
        DatabaseLog     databaseLog = null;
        ;

        select databaseLog
            where databaseLog.logTable == tableName2Id(_tableName)
               && databaseLog.logField == 0
               && databaseLog.logType == _logType;

        if(databaseLog.recId ==0)
        {
            databaseLog.logType = _logType;
            databaseLog.logTable = tableName2Id(_tableName);
            databaseLog.insert();
            if(_infoLog)
            {
                info(strFmt("%1 - %2", _tableName, _logType));
            }
        }
    }
    ;

    if(tableName2Id(tableName)!=0)
    {
        //TODO: 2. Закомментировать ненужные виды логирования
        createDatabaseLog(tableName, DatabaseLogType::Insert); //Вставка
        createDatabaseLog(tableName, DatabaseLogType::Update); //Обновление
        createDatabaseLog(tableName, DatabaseLogType::Delete); //Удаление 
        createDatabaseLog(tableName, DatabaseLogType::RenameKey); //Переименование первичного ключа

        info(int2str(tableName2Id(tableName)));

        SysFlushDatabaseLogSetup::main();
    }
    else
    {
        info(strFmt("Таблица %1 не существует!", tableName));
    }
}

static void FizzBuzz(Args _args)
{
    int i;
    int multipleFizz = 3;
    int multipleBuzz = 5;
    
    str fizzStr = 'Fizz';
    str buzzStr = 'Buzz';
    str fizzBuzzStr = 'FizzBuzz';
    ;

    for(i=1;i<=100;i++)
    {
        if( (i mod multipleFizz != 0) && (i mod multipleBuzz != 0) )
            info(strFmt("%1", i));

        if( (i mod multipleFizz == 0) && (i mod multipleBuzz == 0) )
            info(fizzBuzzStr);

        if( (i mod multipleFizz == 0) && (i mod multipleBuzz != 0) )
            info(fizzStr);

        if( (i mod multipleFizz != 0) && (i mod multipleBuzz == 0) )
            info(buzzStr);
    }
}

static void THK_tableOccenabledFromAOT01(Args _args)
{
    #AOT
    #properties
    TreeNode        TreeNode = TreeNode::findNode(#TablesPath);
    str             tableName;
    str             temporaryProperty;
    sysdictTable    m_dictTable;
    int             i,records,m;
    dictionary      m_dictionary = new dictionary();
    #File
    #WinAPI
    #Avifiles
    CommaIo                 commaIO;
    SysOperationProgress    sysProgress;
    fileName                fileName;
    FileIOPermission        permission;
    int                     start;
;
    if(!Box::yesNo("Are your sure lookup Occenabled table infomation?",dialogButton::No,"Occenabled Table"))
        return;
    fileName = WinAPI::getFolderPath(#CSIDL_Personal) + "\\" + "A02AvgPrice.csv";// + date2str(systemdateget(),321,2,0,2,0,2) + ".CSV";
    permission  = new FileIOPermission(fileName,#io_write);
    permission.assert();
    commaIo = new CommaIo(fileName,#io_write);
    if(!commaIo)
    {
        warning("Please close your csv file and try again. Thanks!");
        return;
    }
    if(commaIo.status() == IO_Status::Ok)
        CommaIo.outFieldDelimiter(",");
    else
        return;
    start = timeNow();
    records = m_dictionary.tableCnt();
    sysProgress = SysOperationProgress::newGeneral(#AviUpdate,"Waitting ... write CSV file",records);
    CommaIo.writeExp(["Id","Table Id","Table Name","Table Label","Occenabled","utilElementType"]);
    for (i = 1; i < records; i++)
    {
        m_dictTable = new sysdictTable(m_dictionary.tableCnt2Id(i));
        sysProgress.incCount(1);
        sysProgress.setText(strfmt("completed %1 [%2]: %3",i/ records * 100, i, m_dictTable.name()));
        if(!m_dictTable.occEnabled())
        {
            m++;
            CommaIo.writeExp([m,m_dictTable.id(),m_dictTable.name(),m_dictTable.label(),m_dictTable.occEnabled(),m_dictTable.utilElementType()]);
        }
        sysProgress.update(true);
    }
    if(m)
    {
        if (winAPI::fileExists(fileName))
        {
            winAPI::shellExecute(fileName);
        }
    }
    CodeAccessPermission::revertAssert();
    info(strfmt("It takes time %1",global::time2StrHMS(timenow() - start)));
    info(strfmt("completed %1 records",m));
}

static void ASB_ExportLicenceFile(Args _args)
{
    SysConfig   sysConfig;
    AsciiIO file = new AsciiIO("c:\\license.txt", "W"); //TODO: указать путь
    ;

    file.read();

    file.write("LicenseVersion 2");
    file.write("");

    select sysConfig
    where sysConfig.configType == ConfigType::LicenseName;  //TODO: изменить значение для версий: AX4.0 - ConfigType::LicensName, AX 2009 - ConfigType::LicenseName
    file.write(strFmt("License #%1", sysConfig.value));

    file.write(" Properties");
    select sysConfig
    where sysConfig.configType == ConfigType::SerialNo;
    file.write(strFmt("  Serial #%1", sysConfig.value));
    file.write(" EndProperties");
    file.write("");
    file.write(" Codes");
    file.write("");

    while select sysConfig
    order by id
    where sysConfig.configType == ConfigType::AccessCodes &&
          sysConfig.value != ""
    {
        file.write(strFmt("  CodeLine #%1", sysConfig.id + 1)); //TODO: проверить зачем к номеру ID прибавляется единица
        file.write(strFmt("    Value #%1", sysConfig.value));
        file.write("  EndCodeLine");
        file.write("");
    }

    file.write(" EndCodes");
    file.write("");
    file.write("EndLicense");

    box::info("Конец!");
}

static void FindFile(Args _args)
{
    #File
    FileName fullFileName(FileName _path, FileName _fileName)
    {
        FileName    pathName;
        FileName    fileName;
        FileName    fileExtension;
        ;
        [pathName,fileName,fileExtension] = fileNameSplit(_fileName);
        return _path + '\\' + fileName + fileExtension;
    }

    void findFiles(FileName _path, 
                  FileName _fileName, 
                  boolean _inclSubDir = true, 
                  FileName _prefix = fullFileName(_path,_fileName))
    {
        FileName    fileName;
        int         hdl;
        ;
        setprefix(_prefix);
        if (WinAPI::folderExists(_path))
        {
            [hdl,fileName] = WinApi::findFirstFile(fullFileName(_path,_fileName));
            while (fileName)
            {
                if (WinAPI::fileExists(fullFileName(_path,fileName)))
                    info(fileName);
                fileName = WinApi::findNextFile(hdl);
            }
            WinApi::findClose(hdl);
            if (_inclSubDir)
            {
                [hdl, fileName] = WinAPI::findFirstFile(_path+'\\'+#AllFiles);
                while (fileName)
                {
                    if (strlwr(fileName) != strlwr(_fileName) &&
                        strlwr(fileName) != strlwr('.')       &&
                        strlwr(fileName) != strlwr('..')      &&
                        WinAPI::pathExists(fullFileName(_path,fileName))
                    )
                        findFiles(fullFileName(_path,fileName), _fileName, _inclSubDir, fileName);
                    fileName = WinApi::findNextFile(hdl);
                }
                WinApi::findClose(hdl);
            }
        }
    }
    findFiles('c:\\Program Files','*.doc');
}